書式設定切替マクロ

• New QX ではメニューの「その他」に「書式設定一覧」という項目が追加になり、現在選択されているものとは違う書式を読み込む手間がかなりわかりやすく簡単になりましたが、一覧を表示して「読み込み」ボタンを押すという手間がかかります。マクロだとメニューから選択すると同時に書式が切り替わります。
• ZIP ファイル ― マクロとマクロメニューに自動追加するための QMA ファイルをまとめたファイルです。
• マクロの内容は次のとおり。

'書式を選択・読込み / Ver. 0.90 for New QX / by kabuneko 2021/03/08
'書式の最大数を30に変更

proc main
    if @hwnd = 0 then exit proc
    dim i, sel, pos, line, top, key$, mode$[32]
    '現在のカーソル位置を保存
    pos = @BytePosCr
    line = @ScrLineToCrLine(@Line)
    top = @Line - @TopLine
 
    'ショートカットキー用文字
    key$ = "ABCDEFGHIJKLMNOPQRSTUVWXYZ1234567890"
 
    '現在の書式番号を取得
    sel = @StyleNo
 
    'メニュー内容を設定
    mode$[1] = "・  書式選択  ・"
    mode$[2] = chr$(1) + "-"
    for i = 1 to 30
        if @@StyleComment$(i) = "" then
            mode$[i+2] = chr$(1) + mid$(key$,i,1) + ". " \
            + "  （設定なし）"
        else
            mode$[i+2] = mid$(key$,i,1)  + ". " \
            + @@StyleComment$(i) + " (" + @@StyleName$(i) + ")"
            if i = sel then mode$[i+2] = chr$(2) + mode$[i+2]
        end if
    next
 
    'メニューを表示・選択アイテムを実行
    sel = popupmenu(mode$)
    if 2 < sel and sel < 33 then @StyleNo = sel-2
 
    'カーソル位置復元
    @Line = @CrLineToScrLine(line)
    @ByteposCr = pos
    @TopLine = @Line - top
end proc